home *** CD-ROM | disk | FTP | other *** search
/ Workbench Add-On / Workbench Add-On - Volume 1.iso / BBS-Archive / Dev / gcc263-src.lha / gcc-2.6.3 / config / msdos / top.sed < prev   
Text File  |  1994-10-30  |  931b  |  39 lines
  1. /\.o[     ]*:/ s/config.status//
  2. /^multilib.h/ s/multilib/not-multilib/
  3. /^target=/ c\
  4. target=go32
  5. /^xmake_file=/ d
  6. /^tmake_file=/ d
  7. /^version=/ c\
  8. version=2.6.1
  9. s/CC = cc/CC = gcc/
  10. s/:\$/: \$/g
  11. s/^    \ *\.\//    go32 /
  12. s/<\ *\$(srcdir)\//< $(srcdir)\\/g
  13. s/^    \$(srcdir)\/move-if-change/    update/
  14. s/^USE_/# USE_/
  15. s/`echo \$(srcdir)\///g
  16. s/ | sed 's,\^\\\.\/,,'`//g
  17. s/^    cd \$(srcdir)[     ]*;/    /
  18. /^# USE_HOST_OBSTACK/ i\
  19. USE_HOST_OBSTACK=obstack.o
  20. /^stamp-attrtab/,/update/ {
  21.   /\\/d
  22.   /fi/d
  23.   /update/ i\
  24.       go32 genattrtab md > t-attrtab.c
  25. }
  26. /^enquire[     ]*:/ s/\$(GCC_PARTS)//g
  27. /^enquire.o[     ]*:/ s/\$(GCC_PASSES)//g
  28. /^GCC_FOR_TARGET =/ c\
  29. GCC_FOR_TARGET = gcc
  30. s/; *@true//
  31. s/stamp-/s-/g
  32. s/tmp-/t-/g
  33. /> *s-objlist/ c\
  34.     echo.exe -o s-objlist $(addprefix ../,$(OBJS) $(BC_OBJS))
  35. /^OBJS.*s-objlist/ s?`cat ../s-objlist`?@../s-objlist?
  36. s/^\(SUBDIR_OBSTACK *=\).*$/\1 ..\/obstack.o/
  37. s/^\(SUBDIR_USE_ALLOCA *=\).*$/\1/
  38. s/^\(SUBDIR_MALLOC *=\).*$/\1/
  39.